35.11. Conversão do PL/SQL do Oracle para o PL/pgSQL do PostgreSQL

Exemplo 35-7. Conversão de uma função simples de PL/SQL para PL/pgSQL

Abaixo está uma função escrita na linguagem PL/SQL do Oracle:

CREATE OR REPLACE FUNCTION cs_fmt_browser_version(v_nome   IN varchar,
                                                  v_versao IN varchar)
RETURN varchar IS
BEGIN
    IF v_versao IS NULL THEN
        RETURN v_nome;
    END IF;
    RETURN v_nome || '/' || v_versao;
END;
/
show errors;

Vamos examinar esta função para ver as diferenças com relação à linguagem PL/pgSQL:

• O Oracle permite que sejam passados parâmetros IN, OUT e INOUT para as funções. Por exemplo, INOUT significa que o parâmetro recebe um valor e retorna outro. O PostgreSQL somente possui parâmetros IN e, portanto, não há especificação do tipo do parâmetro.

• A palavra chave RETURN no protótipo da função (não no corpo da função), no PostgreSQL se torna RETURNS. Além disso, IS se torna AS, e é necessário adicionar a cláusula LANGUAGE, porque a linguagem PL/pgSQL não é a única possível.

• No PostgreSQL o corpo da função é considerado como sendo um literal cadeia de caracteres, portanto é necessário utilizar delimitação por apóstrofos ou cifrão em torno do corpo da função. Isto substitui a barra (/) terminadora da abordagem do Oracle.

• Não existe o comando /show errors no PostgreSQL, e não há necessidade uma vez que os erros são relatados automaticamente.

Abaixo está mostrado como esta função deve se parecer após ser convertida para o PostgreSQL: [2]

CREATE OR REPLACE FUNCTION cs_fmt_browser_version(v_nome   varchar,
                                                  v_versao varchar)
RETURNS varchar AS $$
BEGIN
    IF v_versao IS NULL THEN
        RETURN v_nome;
    END IF;
    RETURN v_nome || '/' || v_versao;
END;
$$ LANGUAGE plpgsql;

Exemplo 35-8. Conversão de uma função que cria outra função de PL/SQL para PL/pgSQL

O procedimento abaixo obtém linhas a partir de uma instrução SELECT, e constrói uma função grande com os resultados em instruções IF, por motivo de eficiência. Em particular, deve ser observada a diferença entre o cursor e o laço FOR.

Esta é a versão Oracle:

CREATE OR REPLACE PROCEDURE cs_update_referrer_type_proc IS
    CURSOR referrer_keys IS
        SELECT * FROM cs_referrer_keys
        ORDER BY try_order;

    func_cmd VARCHAR(4000);
BEGIN
    func_cmd := 'CREATE OR REPLACE FUNCTION cs_find_referrer_type(v_host IN VARCHAR,
                 v_domain IN VARCHAR, v_url IN VARCHAR) RETURN VARCHAR IS BEGIN';

    FOR referrer_key IN referrer_keys LOOP
        func_cmd := func_cmd ||
          ' IF v_' || referrer_key.kind
          || ' LIKE ''' || referrer_key.key_string
          || ''' THEN RETURN ''' || referrer_key.referrer_type
          || '''; END IF;';
    END LOOP;

    func_cmd := func_cmd || ' RETURN NULL; END;';

    EXECUTE IMMEDIATE func_cmd;
END;
/
show errors;

Abaixo está mostrado como esta função ficaria no PostgreSQL:

CREATE OR REPLACE FUNCTION cs_update_referrer_type_proc() RETURNS void AS $func$
DECLARE
    referrer_key RECORD;  -- declare a generic record to be used in a FOR
    func_body text;
    func_cmd text;
BEGIN
    func_body := 'BEGIN' ;

    -- Notice how we scan through the results of a query in a FOR loop
    -- using the FOR <record> construct.

    FOR referrer_key IN SELECT * FROM cs_referrer_keys ORDER BY try_order LOOP
        func_body := func_body ||
          ' IF v_' || referrer_key.kind
          || ' LIKE ' || quote_literal(referrer_key.key_string)
          || ' THEN RETURN ' || quote_literal(referrer_key.referrer_type)
          || '; END IF;' ;
    END LOOP;

    func_body := func_body || ' RETURN NULL; END;';

    func_cmd :=
      'CREATE OR REPLACE FUNCTION cs_find_referrer_type(v_host varchar,
                                                        v_domain varchar,
                                                        v_url varchar)
        RETURNS varchar AS '
      || quote_literal(func_body)
      || ' LANGUAGE plpgsql;' ;

    EXECUTE func_cmd;
    RETURN;
END;
$func$ LANGUAGE plpgsql;

Deve ser observado como o corpo da função é construído em separado e passado através da função quote_literal para duplicar qualquer apóstrofo porventura existente. Esta técnica é necessária, porque não pode ser utilizada a delimitação por cifrão com segurança para definir a nova função: não há certeza de quais cadeias de caracteres serão interpoladas a partir do campo referrer_key.key_string (Aqui é assumido que se pode confiar que referrer_key.kind será sempre host, domain, ou url, mas referrer_key.key_string pode ser qualquer coisa e, em particular, pode conter o caractere cifrão). Na verdade esta função é uma melhoria com relação à original do Oracle, porque não irá gerar código com erro quando referrer_key.key_string ou referrer_key.referrer_type contiverem apóstrofos.

Exemplo 35-9. Conversão de um procedimento com manipulação de cadeia de caracteres e parâmetros OUT de PL/SQL para PL/pgSQL

O procedimento mostrado abaixo, escrito na linguagem PL/SQL do Oracle, é utilizado para analisar uma URL e retornar vários elementos (hospedeiro, caminho e comando). No PostgreSQL, as funções podem retornar apenas um valor. Uma forma de superar este problema é tornar o valor retornado do tipo composto (tipo linha).

Esta é a versão Oracle:

CREATE OR REPLACE PROCEDURE cs_parse_url(
    v_url   IN VARCHAR,
    v_host  OUT VARCHAR,  -- Este é passado de volta,
    v_path  OUT VARCHAR,  -- este também,
    v_query OUT VARCHAR)  -- e este
IS
    a_pos1 INTEGER;
    a_pos2 INTEGER;
BEGIN
    v_host := NULL;
    v_path := NULL;
    v_query := NULL;
    a_pos1 := instr(v_url, '//');

    IF a_pos1 = 0 THEN
        RETURN;
    END IF;
    a_pos2 := instr(v_url, '/', a_pos1 + 2);
    IF a_pos2 = 0 THEN
        v_host := substr(v_url, a_pos1 + 2);
        v_path := '/';
        RETURN;
    END IF;

    v_host := substr(v_url, a_pos1 + 2, a_pos2 - a_pos1 - 2);
    a_pos1 := instr(v_url, '?', a_pos2 + 1);

    IF a_pos1 = 0 THEN
        v_path := substr(v_url, a_pos2);
        RETURN;
    END IF;

    v_path := substr(v_url, a_pos2, a_pos1 - a_pos2);
    v_query := substr(v_url, a_pos1 + 1);
END;
/
show errors;

Abaixo está mostrada uma conversão possível para PL/pgSQL:

CREATE TYPE cs_parse_url_result AS (
    v_host VARCHAR,
    v_path VARCHAR,
    v_query VARCHAR
);

CREATE OR REPLACE FUNCTION cs_parse_url(v_url VARCHAR)
RETURNS cs_parse_url_result AS $$
DECLARE
    res cs_parse_url_result;
    a_pos1 INTEGER;
    a_pos2 INTEGER;
BEGIN
    res.v_host := NULL;
    res.v_path := NULL;
    res.v_query := NULL;
    a_pos1 := instr(v_url, '//');

    IF a_pos1 = 0 THEN
        RETURN res;
    END IF;
    a_pos2 := instr(v_url, '/', a_pos1 + 2);
    IF a_pos2 = 0 THEN
        res.v_host := substr(v_url, a_pos1 + 2);
        res.v_path := '/';
        RETURN res;
    END IF;

    res.v_host := substr(v_url, a_pos1 + 2, a_pos2 - a_pos1 - 2);
    a_pos1 := instr(v_url, '?', a_pos2 + 1);

    IF a_pos1 = 0 THEN
        res.v_path := substr(v_url, a_pos2);
        RETURN res;
    END IF;

    res.v_path := substr(v_url, a_pos2, a_pos1 - a_pos2);
    res.v_query := substr(v_url, a_pos1 + 1);
    RETURN res;
END;
$$ LANGUAGE plpgsql;

Esta função poderia ser utilizada da seguinte maneira:

SELECT * FROM cs_parse_url('http://foobar.com/query.cgi?baz');

   v_host   |   v_path   | v_query
------------+------------+---------
 foobar.com | /query.cgi | baz
(1 linha)

Exemplo 35-10. Conversão de um procedimento de PL/SQL para PL/pgSQL

A versão Oracle:

CREATE OR REPLACE PROCEDURE cs_create_job(v_job_id IN INTEGER) IS
    a_running_job_count INTEGER;
    PRAGMA AUTONOMOUS_TRANSACTION;(1)
BEGIN
    LOCK TABLE cs_jobs IN EXCLUSIVE MODE;(2)

    SELECT count(*) INTO a_running_job_count FROM cs_jobs WHERE end_stamp IS NULL;

    IF a_running_job_count > 0 THEN
        COMMIT; -- liberar bloqueio(3)
        raise_application_error(-20000,
            'Não foi possível criar uma nova tarefa: já há uma em execução.');
    END IF;

    DELETE FROM cs_active_job;
    INSERT INTO cs_active_job(job_id) VALUES (v_job_id);

    BEGIN
        INSERT INTO cs_jobs (job_id, start_stamp) VALUES (v_job_id, sysdate);
    EXCEPTION
        WHEN dup_val_on_index THEN NULL; -- não se preocupar se já existe
    END;
    COMMIT;
END;
/
show errors

Procedimentos como este podem ser facilmente convertidos em funções PostgreSQL que retornam void. Este procedimento, em particular, é interessante porque pode ensinar algumas coisas:

Abaixo está mostrada uma maneira de como esta função poderia ser convertida para PL/pgSQL:

CREATE OR REPLACE FUNCTION cs_create_job(v_job_id integer) RETURNS void AS $$
DECLARE
    a_running_job_count integer;
BEGIN
    LOCK TABLE cs_jobs IN EXCLUSIVE MODE;

    SELECT count(*) INTO a_running_job_count FROM cs_jobs WHERE end_stamp IS NULL;

    IF a_running_job_count > 0 THEN
        RAISE EXCEPTION 'Não foi possível criar uma nova tarefa: já há uma em execução.';(1)
    END IF;

    DELETE FROM cs_active_job;
    INSERT INTO cs_active_job(job_id) VALUES (v_job_id);

    BEGIN
        INSERT INTO cs_jobs (job_id, start_stamp) VALUES (v_job_id, now());
    EXCEPTION
        WHEN unique_violation THEN (2)
            -- não se preocupar se já existe
    END;

    RETURN;
END;
$$ LANGUAGE plpgsql;

A principal diferença funcional entre este procedimento e o equivalente do Oracle é que o bloqueio exclusivo na tabela cs_jobs é mantido até o término da transação que fez a chamada. Também, se quem fez a chamada for posteriormente interrompido (por exemplo, devido a um erro), os efeitos deste procedimento serão desfeitos.